.版本 2

.程序集 集_值读取

.子程序 易代码读取, 文本型, , 成功返回易语言格式
.参数 类型, 文本型, , 如：常量、类、DLL
.参数 tag, 整数型

类型 ＝ 删首尾空 (类型)
全_当前选中项数据.类型 ＝ 类型
.判断开始 (类型 ＝ “常量”)
    全_当前选中项数据.易代码 ＝ 功能_取常量代码 (tag)

.判断 (类型 ＝ “全局变量”)
    全_当前选中项数据.易代码 ＝ 功能_取全局变量代码 (tag)

.判断 (类型 ＝ “DLL命令”)
    全_当前选中项数据.易代码 ＝ 功能_取DLL代码 (tag)

.判断 (类型 ＝ “数据类型”)
    全_当前选中项数据.易代码 ＝ 功能_取数据类型代码 (tag)

.判断 (类型 ＝ “子程序”)
    全_当前选中项数据.易代码 ＝ 功能_取子程序代码 (tag)

.判断 (类型 ＝ “类”)
    全_当前选中项数据.易代码 ＝ 功能_取子程序代码 (tag)

.判断 (类型 ＝ “图片资源”)
    全_当前选中项数据.易代码 ＝ 功能_取图片声音 (tag)

.判断 (类型 ＝ “声音资源”)
    全_当前选中项数据.易代码 ＝ 功能_取图片声音 (tag)
.默认

.判断结束
返回 (全_当前选中项数据.易代码)

.子程序 易备注读取, 文本型
.参数 类型, 文本型, , 如：常量、类、DLL
.参数 tag, 整数型
.局部变量 备注信息, 文本型

类型 ＝ 删首尾空 (类型)
全_当前选中项数据.类型 ＝ 类型

.如果真 (类型 ＝ “” 或 tag ＝ 0)
    返回 (“”)
.如果真结束
' 输出调试文本 (类型, tag)

.判断开始 (类型 ＝ “常量”)
    全_当前选中项数据.易代码 ＝ 功能_取常量备注 (tag)

.判断 (类型 ＝ “全局变量”)
    全_当前选中项数据.易代码 ＝ 功能_取全局变量备注 (tag)

.判断 (类型 ＝ “DLL命令”)
    全_当前选中项数据.易代码 ＝ 功能_取DLL备注 (tag)

.判断 (类型 ＝ “数据类型”)
    全_当前选中项数据.易代码 ＝ 功能_取数据类型备注 (tag)

.判断 (类型 ＝ “子程序”)
    全_当前选中项数据.易代码 ＝ 功能_取子程序备注 (tag)

.判断 (类型 ＝ “类”)
    全_当前选中项数据.易代码 ＝ 功能_取子程序备注 (tag)

.判断 (类型 ＝ “图片资源”)
    全_当前选中项数据.易代码 ＝ 功能_取图片声音备注 (tag)

.判断 (类型 ＝ “声音资源”)
    全_当前选中项数据.易代码 ＝ 功能_取图片声音备注 (tag)
.默认

.判断结束
返回 (全_当前选中项数据.易代码)


.子程序 _资源类型识别, 整数型, , 成功返回资源类型，失败返回0(未知格式)，0=未知，1=图片，2=声音，3=exe、4=epk
.参数 Path, 文本型, 可空, 如果是图片，此变量将自动返回图片路径
.局部变量 资源MD5, 文本型
.局部变量 局_资源类型, 整数型, , , 0=未知，1=图片，2=声音，3=exe、4=epk
.局部变量 图标_播放, 文本型
.局部变量 图标_停止, 文本型

资源MD5 ＝ 校验_取md5 (全_当前选中项数据.字节集数据)
局_资源类型 ＝ 0
.判断开始 (取字节集左边 (全_当前选中项数据.字节集数据, 6) ＝ { 137, 80, 78, 71, 13, 10 })  ' PNG
    全_当前选中项数据.文件路径 ＝ 目录_取临时目录 () ＋ 资源MD5 ＋ “.png”
    全_当前选中项数据.文件格式 ＝ “(PNG)”
    全_当前选中项数据.保存文件的过虑器 ＝ “PNG图片|*.png|”
    局_资源类型 ＝ 1

.判断 (取字节集左边 (全_当前选中项数据.字节集数据, 3) ＝ { 66, 77, 246 })  ' BMP
    全_当前选中项数据.文件路径 ＝ 目录_取临时目录 () ＋ 资源MD5 ＋ “.bmp”
    全_当前选中项数据.文件格式 ＝ “(BMP)”
    全_当前选中项数据.保存文件的过虑器 ＝ “BMP图片|*.bmp|”
    局_资源类型 ＝ 1

.判断 (取字节集左边 (全_当前选中项数据.字节集数据, 3) ＝ { 71, 73, 70 })  ' GIF
    全_当前选中项数据.文件路径 ＝ 目录_取临时目录 () ＋ 资源MD5 ＋ “.gif”
    全_当前选中项数据.文件格式 ＝ “(GIF)”
    全_当前选中项数据.保存文件的过虑器 ＝ “GID动画图片|*.gif|”
    局_资源类型 ＝ 1

.判断 (取字节集左边 (全_当前选中项数据.字节集数据, 4) ＝ { 255, 216, 255, 224 })  ' JPG
    全_当前选中项数据.文件路径 ＝ 目录_取临时目录 () ＋ 资源MD5 ＋ “.jpg”
    全_当前选中项数据.文件格式 ＝ “(JPG)”
    全_当前选中项数据.保存文件的过虑器 ＝ “JPG图片|*.jpg|”
    局_资源类型 ＝ 1

.判断 (取字节集左边 (全_当前选中项数据.字节集数据, 4) ＝ { 0, 0, 1, 0 })  ' ICO
    全_当前选中项数据.文件路径 ＝ 目录_取临时目录 () ＋ 资源MD5 ＋ “.ico”
    全_当前选中项数据.文件格式 ＝ “(ICO)”
    全_当前选中项数据.保存文件的过虑器 ＝ “ICO图标|*.ico|”
    局_资源类型 ＝ 1

.判断 (取字节集左边 (全_当前选中项数据.字节集数据, 4) ＝ { 82, 73, 70, 70 })  ' WAV
    全_当前选中项数据.文件路径 ＝ 目录_取临时目录 () ＋ 资源MD5 ＋ “.wav”
    全_当前选中项数据.文件格式 ＝ “(WAV)”
    全_当前选中项数据.保存文件的过虑器 ＝ “WAV声音|*.wav|”
    局_资源类型 ＝ 2

.判断 (取字节集左边 (全_当前选中项数据.字节集数据, 5) ＝ { 48, 38, 178, 117, 142 })  ' WMA
    全_当前选中项数据.文件路径 ＝ 目录_取临时目录 () ＋ 资源MD5 ＋ “.wma”
    全_当前选中项数据.文件格式 ＝ “(WMA)”
    全_当前选中项数据.保存文件的过虑器 ＝ “WMA声音|*.wma|”
    局_资源类型 ＝ 2

.判断 (取字节集左边 (全_当前选中项数据.字节集数据, 4) ＝ { 77, 84, 104, 100 })  ' MID
    全_当前选中项数据.文件路径 ＝ 目录_取临时目录 () ＋ 资源MD5 ＋ “.mid”
    全_当前选中项数据.文件格式 ＝ “(MID)”
    全_当前选中项数据.保存文件的过虑器 ＝ “MID声音|*.mid|”
    局_资源类型 ＝ 2

.判断 (取字节集左边 (全_当前选中项数据.字节集数据, 3) ＝ { 73, 68, 51 } 或 取字节集左边 (全_当前选中项数据.字节集数据, 4) ＝ { 255, 250, 146, 192 })  ' MP3
    全_当前选中项数据.文件路径 ＝ 目录_取临时目录 () ＋ 资源MD5 ＋ “.mp3”
    全_当前选中项数据.文件格式 ＝ “(MP3)”
    全_当前选中项数据.保存文件的过虑器 ＝ “MP3声音|*.mp3|”
    局_资源类型 ＝ 2

.判断 (取字节集左边 (全_当前选中项数据.字节集数据, 2) ＝ { 77, 90 })  ' EXE,DLL
    全_当前选中项数据.文件路径 ＝ 目录_取临时目录 () ＋ 资源MD5 ＋ “.dll”
    全_当前选中项数据.文件格式 ＝ “(DLL)”
    全_当前选中项数据.保存文件的过虑器 ＝ “可执行文件|*.dll;*.exe|”
    局_资源类型 ＝ 3

.判断 (取字节集左边 (全_当前选中项数据.字节集数据, 36) ＝ { 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 })  ' EPK
    .如果真 (寻找字节集 (全_当前选中项数据.字节集数据, { 207, 181, 205, 179, 186, 203, 208, 196, 214, 167, 179, 214, 191, 226 }, ) ≠ -1)
        全_当前选中项数据.文件路径 ＝ 目录_取临时目录 () ＋ 资源MD5 ＋ “.epk”
        全_当前选中项数据.文件格式 ＝ “(易包文件)”
        全_当前选中项数据.保存文件的过虑器 ＝ “易包文件|*.epk|”
        局_资源类型 ＝ 4
    .如果真结束

.默认

    全_当前选中项数据.保存文件的过虑器 ＝ “”
.判断结束

.如果真 (局_资源类型 ＞ 0)
    .如果真 (文件是否存在 (全_当前选中项数据.文件路径) ＝ 假 且 局_资源类型 ≠ 3)
        写到文件 (全_当前选中项数据.文件路径, 全_当前选中项数据.字节集数据)
    .如果真结束

    .判断开始 (局_资源类型 ＝ 1)
        Path ＝ “<img src=” ＋ #引号 ＋ 全_当前选中项数据.文件路径 ＋ #引号 ＋ “/>”

    .判断 (局_资源类型 ＝ 2)
        Path ＝ #HTML_声音_播放图标
        图标_播放 ＝ 目录_取临时目录 () ＋ “play.png”
        .如果真 (校验_取md5 (读入文件 (图标_播放)) ≠ “b6f43170322f6cda9f5a9cb38db305c9”)
            写到文件 (图标_播放, #图片_播放图标)
        .如果真结束

        图标_停止 ＝ 目录_取临时目录 () ＋ “stop.png”
        .如果真 (校验_取md5 (读入文件 (图标_停止)) ≠ “c3439d1f096e3a7e5b78552a724ed764”)
            写到文件 (图标_停止, #图片_停止播放)
        .如果真结束

        Path ＝ 子文本替换 (Path, “<play>”, 图标_播放, , 1, 真)
        Path ＝ 子文本替换 (Path, “<stop>”, 图标_停止, , 1, 真)
    .默认

    .判断结束

.如果真结束
返回 (局_资源类型)

.子程序 取模块MD5, 文本型
.局部变量 MD5, 文本型, 静态

.如果真 (MD5 ≠ “”)
    返回 (MD5)
.如果真结束
MD5 ＝ 校验_取md5 (读入文件 (全_模块信息.模块路径))
返回 (MD5)
